STATIC _HMG_STATIC  
  
 *-----------------------------------------------------------------------------* 
 FUNCTION _SetGetGlobal( cVarName, xNewValue ) 
 *-----------------------------------------------------------------------------* 
  
    LOCAL xOldValue 
     
    IF _HMG_STATIC == NIL ; _HMG_STATIC := oHmgData() 
    ENDIF 
     
    IF pCount() == 0 
       RETURN _HMG_STATIC  
        
    ELSEIF pCount() == 1 
       RETURN _HMG_STATIC:Get(cVarName, Nil) 
     
    ELSEIF pCount() == 2 
       xOldValue := _HMG_STATIC:Get(cVarName, Nil) 
       IF ISNIL( xNewValue ) ; _HMG_STATIC:Del(cVarName) 
       ELSE                  ; _HMG_STATIC:Set(cVarName, xNewValue) 
       ENDIF 
    ENDIF    
  
 RETURN xOldValue 
  
 *-----------------------------------------------------------------------------* 
 FUNCTION oHmgData( lUpper ) 
 *-----------------------------------------------------------------------------* 
    hb_default( @lUpper, .T. ) 
 RETURN THmgData():New( lUpper ) 
  
 /////////////////////////////////////////////////////////////////////////////// 
 CLASS THmgData 
 /////////////////////////////////////////////////////////////////////////////// 
  
    PROTECTED: 
    VAR lUpp  AS LOGICAL 
    VAR aKey              INIT hb_Hash() 
  
    EXPORTED: 
    VAR Cargo 
  
    METHOD New( lUpper ) INLINE ( ::lUpp := !Empty( lUpper ), Self ) CONSTRUCTOR 
  
    METHOD Set( Key, Block ) INLINE iif( HB_ISHASH( Key ), ::aKey := Key, hb_HSet ( ::aKey, ::Upp( Key ), Block ) ) 
    METHOD Get( Key, Def )   INLINE hb_HGetDef( ::aKey, ::Upp( Key ), Def ) 
    METHOD Del( Key ) INLINE iif( ::Pos( Key ) > 0, hb_HDel( ::aKey, ::Upp( Key ) ), Nil ) 
    METHOD Pos( Key ) INLINE hb_HPos( ::aKey, ::Upp( Key ) ) 
    METHOD Upp( Key ) INLINE iif( HB_ISCHAR(Key) .and. ::lUpp, Upper( Key ), Key ) 
    METHOD Len()      INLINE Len( ::aKey ) 
  
    METHOD Keys()      INLINE hb_HKeys( ::aKey ) 
    METHOD Values()    INLINE hb_HValues( ::aKey ) 
    METHOD CloneHash() INLINE hb_HClone( ::aKey ) 
  
    _METHOD GetAll( lAll ) 
    _METHOD Eval( Block ) 
    _METHOD Destroy() 
  
    ERROR HANDLER ControlAssign 
  
 ENDCLASS 
 /////////////////////////////////////////////////////////////////////////////// 
  
 METHOD GetAll( lAll ) CLASS THmgData 
  
    LOCAL aRet := {} 
  
    IF HB_ISLOGICAL( lAll ) .AND. lAll 
       ::Eval( {| val | AAdd( aRet, val ) } ) 
    ELSE 
       ::Eval( {| val, Key | AAdd( aRet, { Key, val } ) } ) 
    ENDIF 
  
 RETURN aRet 
  
 METHOD Eval( Block ) CLASS THmgData 
  
    LOCAL i, b := HB_ISBLOCK( Block ) 
    LOCAL l := HB_ISLOGICAL( Block ) .AND. Block 
    LOCAL a := iif( b, NIL, Array( 0 ) ) 
  
    FOR i := 1 TO ::Len() 
       IF b ; Eval( Block, hb_HValueAt( ::aKey, i ), hb_HKeyAt( ::aKey, i ), i ) 
       ELSEIF l ; AAdd( a, hb_HValueAt( ::aKey, i ) ) 
       ELSE ; AAdd( a, { hb_HValueAt( ::aKey, i ), hb_HKeyAt( ::aKey, i ), i } ) 
       ENDIF 
    NEXT 
  
 RETURN a 
  
 METHOD Destroy() CLASS THmgData 
  
    LOCAL i, k, o 
  
    IF HB_ISHASH( ::aKey ) 
       FOR i := 1 TO Len( ::aKey ) 
          k := hb_HKeyAt( ::aKey, i ) 
          hb_HSet( ::aKey, k, Nil ) 
          hb_HDel( ::aKey, k ) 
       NEXT 
    ENDIF 
  
    IF HB_ISOBJECT( ::Cargo ) .AND. ::Cargo:ClassName == ::ClassName 
       o := ::Cargo 
       IF HB_ISHASH( o:aKey ) 
          FOR i := 1 TO Len( o:aKey ) 
             k := hb_HKeyAt( o:aKey, i ) 
             hb_HSet( o:aKey, k, Nil ) 
             hb_HDel( o:aKey, k ) 
          NEXT 
       ENDIF 
    ENDIF 
  
 RETURN NIL 
  
 METHOD ControlAssign( xValue ) CLASS THmgData 
  
    LOCAL cMessage, uRet, lError 
  
    cMessage := __GetMessage() 
    lError := .T. 
  
    IF PCount() == 0 
       uRet := ::Get( cMessage ) 
       lError := .F. 
    ELSEIF PCount() == 1 
       ::Set( SubStr( cMessage, 2 ), xValue ) 
       uRet := ::Get( cMessage ) 
       lError := .F. 
    ENDIF 
  
    IF lError 
       uRet := NIL 
       ::MsgNotFound( cMessage ) 
    ENDIF 
  
 RETURN uRet